Perform more work in boot.s

Author: phil-opp

real_mode/src/boot.s

@@ -22,8 +22,88 @@ _start:
     # initialize stack
     mov sp, 0x7c00
 
+enable_a20:
+    # enable A20-Line via IO-Port 92, might not work on all motherboards
+    in al, 0x92
+    test al, 2
+    jnz enable_a20_after
+    or al, 2
+    and al, 0xFE
+    out 0x92, al
+enable_a20_after:
+
+enter_protected_mode:
+    # clear interrupts
+    cli
+    push ds
+    push es
+
+    lgdt [gdt32info]
+
+    mov eax, cr0
+    or al, 1    # set protected mode bit
+    mov cr0, eax
+
+    jmp protected_mode                # tell 386/486 to not crash
+
+protected_mode:
+    mov bx, 0x10
+    mov ds, bx # set data segment
+    mov es, bx # set extra segment
+
+    and al, 0xfe    # clear protected mode bit
+    mov cr0, eax
+
+unreal_mode:
+    pop es # get back old extra segment
+    pop ds # get back old data segment
+    sti
+
+    # back to real mode, but internal data segment register is still loaded
+    # with gdt segment -> we can access the full 4GiB of memory
+
+    mov bx, 0x0f01         # attrib/char of smiley
+    mov eax, 0xb8f00       # note 32 bit offset
+    mov word ptr ds:[eax], bx
+
+check_int13h_extensions:
+    mov ah, 0x41
+    mov bx, 0x55aa
+    # dl contains drive number
+    int 0x13
+    jc no_int13h_extensions
+
+rust:
+    push dx     # pass disk number as argument
     call rust_main
 
 spin:
     hlt
     jmp spin
+
+gdt32info:
+   .word gdt32_end - gdt32 - 1  # last byte in table
+   .word gdt32                  # start of table
+
+gdt32:
+    # entry 0 is always unused
+    .quad 0
+codedesc:
+    .byte 0xff
+    .byte 0xff
+    .byte 0
+    .byte 0
+    .byte 0
+    .byte 0x9a
+    .byte 0xcf
+    .byte 0
+datadesc:
+    .byte 0xff
+    .byte 0xff
+    .byte 0
+    .byte 0
+    .byte 0
+    .byte 0x92
+    .byte 0xcf
+    .byte 0
+gdt32_end: