Declarations4: add RULE-8-6

and refactor RULE-5-7 for lib mv

Author: knewbury01

c/misra/src/rules/RULE-5-7/TagNameNotUnique.ql

@@ -14,7 +14,7 @@
 
 import cpp
 import codingstandards.c.misra
-import codingstandards.c.Identifiers
+import codingstandards.cpp.Identifiers
 
 from Struct s, InterestingIdentifiers s2
 where

c/misra/src/rules/RULE-8-6/IdentifierWithExternalLinkageOneDefinition.ql

@@ -0,0 +1,38 @@
+/**
+ * @id c/misra/identifier-with-external-linkage-one-definition
+ * @name RULE-8-6: An identifier with external linkage shall have exactly one external definition
+ * @description An identifier with multiple definitions in different translation units leads to
+ *              undefined behavior.
+ * @kind problem
+ * @precision high
+ * @problem.severity error
+ * @tags external/misra/id/rule-8-6
+ *       correctness
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.c.misra
+import codingstandards.cpp.Identifiers
+
+from ExternalIdentifiers d, DeclarationEntry de1, DeclarationEntry de2
+where
+  not isExcluded(d, Declarations4Package::identifierWithExternalLinkageOneDefinitionQuery()) and
+  not isExcluded([de1, de2], Declarations4Package::identifierWithExternalLinkageOneDefinitionQuery()) and
+  d.isTopLevel() and
+  d = de1.getDeclaration() and
+  d = de2.getDeclaration() and
+  de1 != de2 and
+  de1.isDefinition() and
+  de2.isDefinition() and
+  //exceptions
+  (d instanceof Function implies not d.(Function).isInline()) and
+  // Apply an ordering based on ___location to enforce that (de1, de2) = (de2, de1) and we only report (de1, de2).
+  (
+    de1.getFile().getAbsolutePath() < de2.getFile().getAbsolutePath()
+    or
+    de1.getFile().getAbsolutePath() = de2.getFile().getAbsolutePath() and
+    de1.getLocation().getStartLine() < de2.getLocation().getStartLine()
+  )
+select de1, "The identifier " + de1.getName() + " has external linkage and is redefined $@.", de2,
+  "here"

c/misra/test/rules/RULE-8-6/IdentifierWithExternalLinkageOneDefinition.expected

@@ -0,0 +1,2 @@
+| test.c:1:5:1:6 | definition of g1 | The identifier g1 has external linkage and is redefined $@. | test1.c:1:5:1:6 | definition of g1 | here |
+| test.c:6:6:6:7 | definition of f2 | The identifier f2 has external linkage and is redefined $@. | test1.c:6:6:6:7 | definition of f2 | here |

c/misra/test/rules/RULE-8-6/IdentifierWithExternalLinkageOneDefinition.qlref

@@ -0,0 +1 @@
+rules/RULE-8-6/IdentifierWithExternalLinkageOneDefinition.ql

c/misra/test/rules/RULE-8-6/test.c

@@ -0,0 +1,6 @@
+int g1 = 1;        // NON_COMPLIANT
+static int g2 = 1; // COMPLIANT; internal linkage
+
+inline void f1() {} // COMPLIANT; inline functions are an exception
+
+void f2() {} // NON_COMPLIANT

c/misra/test/rules/RULE-8-6/test1.c

@@ -0,0 +1,6 @@
+int g1 = 0;        // NON_COMPLIANT
+static int g2 = 1; // COMPLIANT; internal linkage
+
+inline void f1() {} // COMPLIANT; inline functions are an exception
+
+void f2() {} // NON_COMPLIANT

c/common/src/codingstandards/c/Identifiers.qll renamed to cpp/common/src/codingstandards/cpp/Identifiers.qll

@@ -1,4 +1,19 @@
 import cpp
+import codingstandards.cpp.Linkage
+
+class ExternalIdentifiers extends InterestingIdentifiers {
+  ExternalIdentifiers() {
+    hasExternalLinkage(this) and
+    getNamespace() instanceof GlobalNamespace
+  }
+
+  string getSignificantName() {
+    //C99 states the first 31 characters of external identifiers are significant
+    //C90 states the first 6 characters of external identifiers are significant and case is not required to be significant
+    //C90 is not currently considered by this rule
+    result = this.getName().prefix(31)
+  }
+}
 
 //Identifiers that are candidates for checking uniqueness
 class InterestingIdentifiers extends Declaration {

cpp/common/src/codingstandards/cpp/exclusions/c/Declarations4.qll

@@ -0,0 +1,25 @@
+//** THIS FILE IS AUTOGENERATED, DO NOT MODIFY DIRECTLY.  **/
+import cpp
+import RuleMetadata
+import codingstandards.cpp.exclusions.RuleMetadata
+
+newtype Declarations4Query = TIdentifierWithExternalLinkageOneDefinitionQuery()
+
+predicate isDeclarations4QueryMetadata(Query query, string queryId, string ruleId) {
+  query =
+    // `Query` instance for the `identifierWithExternalLinkageOneDefinition` query
+    Declarations4Package::identifierWithExternalLinkageOneDefinitionQuery() and
+  queryId =
+    // `@id` for the `identifierWithExternalLinkageOneDefinition` query
+    "c/misra/identifier-with-external-linkage-one-definition" and
+  ruleId = "RULE-8-6"
+}
+
+module Declarations4Package {
+  Query identifierWithExternalLinkageOneDefinitionQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `identifierWithExternalLinkageOneDefinition` query
+      TQueryC(TDeclarations4PackageQuery(TIdentifierWithExternalLinkageOneDefinitionQuery()))
+  }
+}

cpp/common/src/codingstandards/cpp/exclusions/c/RuleMetadata.qll

@@ -12,6 +12,7 @@ import Contracts3
 import Declarations1
 import Declarations2
 import Declarations3
+import Declarations4
 import Expressions
 import IO1
 import IO2
@@ -44,6 +45,7 @@ newtype TCQuery =
   TDeclarations1PackageQuery(Declarations1Query q) or
   TDeclarations2PackageQuery(Declarations2Query q) or
   TDeclarations3PackageQuery(Declarations3Query q) or
+  TDeclarations4PackageQuery(Declarations4Query q) or
   TExpressionsPackageQuery(ExpressionsQuery q) or
   TIO1PackageQuery(IO1Query q) or
   TIO2PackageQuery(IO2Query q) or
@@ -76,6 +78,7 @@ predicate isQueryMetadata(Query query, string queryId, string ruleId) {
   isDeclarations1QueryMetadata(query, queryId, ruleId) or
   isDeclarations2QueryMetadata(query, queryId, ruleId) or
   isDeclarations3QueryMetadata(query, queryId, ruleId) or
+  isDeclarations4QueryMetadata(query, queryId, ruleId) or
   isExpressionsQueryMetadata(query, queryId, ruleId) or
   isIO1QueryMetadata(query, queryId, ruleId) or
   isIO2QueryMetadata(query, queryId, ruleId) or

cpp/common/src/codingstandards/cpp/rules/notdistinctidentifier/NotDistinctIdentifier.qll

@@ -5,28 +5,7 @@
 import cpp
 import codingstandards.cpp.Customizations
 import codingstandards.cpp.Exclusions
-import codingstandards.cpp.Linkage
-
-class ExternalIdentifiers extends Declaration {
-  ExternalIdentifiers() {
-    this.getName().length() >= 31 and
-    hasExternalLinkage(this) and
-    getNamespace() instanceof GlobalNamespace and
-    not this.isFromTemplateInstantiation(_) and
-    not this.isFromUninstantiatedTemplate(_) and
-    not this.hasDeclaringType() and
-    not this instanceof UserType and
-    not this instanceof Operator and
-    not this.hasName("main")
-  }
-
-  string getSignificantName() {
-    //C99 states the first 31 characters of external identifiers are significant
-    //C90 states the first 6 characters of external identifiers are significant and case is not required to be significant
-    //C90 is not currently considered by this rule
-    result = this.getName().prefix(31)
-  }
-}
+import codingstandards.cpp.Identifiers
 
 abstract class NotDistinctIdentifierSharedQuery extends Query { }
 
@@ -35,6 +14,8 @@ Query getQuery() { result instanceof NotDistinctIdentifierSharedQuery }
 query predicate problems(ExternalIdentifiers d, ExternalIdentifiers d2, string message) {
   not isExcluded(d, getQuery()) and
   not isExcluded(d, getQuery()) and
+  d.getName().length() >= 31 and
+  d2.getName().length() >= 31 and
   not d = d2 and
   d.getLocation().getStartLine() >= d2.getLocation().getStartLine() and
   d.getSignificantName() = d2.getSignificantName() and