Java: incorporate SMAP locations into Top.hasLocationInfo

Author: yo-h

java/ql/src/semmle/code/Location.qll

@@ -6,6 +6,7 @@
 
 import FileSystem
 import semmle.code.java.Element
+import semmle.code.SMAP
 
 /** Holds if element `e` has name `name`. */
 predicate hasName(Element e, string name) {
@@ -61,6 +62,18 @@ class Top extends @top {
    */
   predicate hasLocationInfo(
     string filepath, int startline, int startcolumn, int endline, int endcolumn
+  ) {
+    hasLocationInfoAux(filepath, startline, startcolumn, endline, endcolumn)
+    or
+    exists(string outFilepath, int outStartline, int outEndline |
+      hasLocationInfoAux(outFilepath, outStartline, _, outEndline, _) and
+      hasSmapLocationInfo(filepath, startline, startcolumn, endline, endcolumn, outFilepath,
+        outStartline, outEndline)
+    )
+  }
+
+  predicate hasLocationInfoAux(
+    string filepath, int startline, int startcolumn, int endline, int endcolumn
   ) {
     exists(File f, Location l | fixedHasLocation(this, l, f) |
       locations_default(l, f, startline, startcolumn, endline, endcolumn) and

java/ql/src/semmle/code/SMAP.qll

@@ -0,0 +1,36 @@
+import java
+
+predicate smap(File inputFile, int inLine, File outputFile, int outLineStart, int outLineEnd) {
+  exists(
+    string defaultStratum, int inputFileNum, int inStart, int inCount, int outStart, int outIncr,
+    int n
+  |
+    smap_header(outputFile, _, defaultStratum) and
+    smap_files(outputFile, defaultStratum, inputFileNum, _, inputFile) and
+    smap_lines(outputFile, defaultStratum, inputFileNum, inStart, inCount, outStart, outIncr) and
+    inLine in [inStart .. inStart + inCount - 1] and
+    outLineStart = outStart + n * outIncr and
+    outLineEnd = (n + 1) * outIncr - 1 + outStart and
+    n = inLine - inStart
+  )
+}
+
+predicate smap(File inputFile, int inLine, File outputFile, int outLine) {
+  exists(int outLineStart, int outLineEnd |
+    smap(inputFile, inLine, outputFile, outLineStart, outLineEnd) and
+    outLine in [outLineStart .. outLineEnd]
+  )
+}
+
+predicate hasSmapLocationInfo(
+  string inputPath, int isl, int isc, int iel, int iec, string outputPath, int osl, int oel
+) {
+  exists(File inputFile, File outputFile |
+    inputPath = inputFile.getAbsolutePath() and
+    outputPath = outputFile.getAbsolutePath() and
+    smap(inputFile, isl, outputFile, osl) and
+    smap(inputFile, iel - 1, outputFile, oel) and
+    isc = 1 and
+    iec = 0
+  )
+}